#!/usr/bin/perl
#####################################################################
# Function: pg-rex_archivefile_delete
#
#
# 概要:
# PG-REX でのアーカイブ削除用の実行ツール。
# 手順の簡易化を目的として作成している。
# 
# 特記事項:
# なし
#
# Copyright (c) 2012,2013, NIPPON TELEGRAPH AND TELEPHONE CORPORATION
#
#####################################################################
use warnings;
use strict;
use Getopt::Long;
use lib qw(/usr/local/share/pg-rex);
use include::command;
use common qw(read_config read_cib exec_command ssh_exec_command get_recoverywal
              get_node get_pg_command_path check_user printlog);

BEGIN {
    if ($ENV{"LANG"} =~ m/ja/i){
        eval qq{
            use po::ja;
        };
    }
    else{
        eval qq{
            use po::en;
        }
    }
};

$SIG{INT} = sub {
    printlog("LOG", ARCHDELETE_MS0001);
};

main();

1;

sub main{
    my $kill_when_no_data = 0;
    my $result;
    my @results;
    my $help_mode = 0;
    my $force_mode = 0;
    my $mv_mode = 0;
    my $rm_mode = 0;
    my $ssh_pass_another_node;
    my $ssh_pass_backup_node;

    # 標準出力が途中で停止するのを防ぐ為に
    # 標準出力のオートフラッシュを有効化
    $| = 1;

    ### スクリプト実行準備 ###
    # 実行ユーザの確認
    check_user();

    # オプション解析
    GetOptions('help'   => \$help_mode,
               'force'  => \$force_mode,
               'move'   => \$mv_mode,
               'remove' => \$rm_mode);
    my $backup_pgdata = shift(@ARGV);

    if ($help_mode || (!$mv_mode && !$rm_mode)){
        printlog("USAGE", ARCHDELETE_USAGE);
        exit(0);
    }

    if ($mv_mode && $rm_mode){
        printlog("ERROR", ARCHDELETE_MS0002);
    }

    printlog("LOG", ARCHDELETE_MS0003);

    my $mode = "rm";
    if ($mv_mode) {
        $mode = "mv";
        printlog("LOG", ARCHDELETE_MS0004);
    }
    else {
        printlog("LOG", ARCHDELETE_MS0005);
    }

    my $backup_node;
    my $backup_path;
    if ($backup_pgdata){
        # backup path format : <host name>:/<path name> or /<path name>
        # <host name>には「:」や「@」を含まない
        if ($backup_pgdata !~ /^(([^:@;|&]+):)?(\/.+)$/) {
            printlog("ERROR", ARCHDELETE_MS0006, $backup_pgdata);
        }
        $backup_node = $2;
        $backup_path = $3;
        
        if (!$backup_node){
            $backup_node = 'localhost';
        }
    }
    elsif (!$force_mode){
        printlog("LOG", ARCHDELETE_MS0007);
        my $input_node = <STDIN>;
        chomp $input_node;
        # backup host name format : <host name>
        # <host name>には「:」や「@」を含まない
        if ($input_node){
            if ($input_node !~ /^[^:@\s;|&]+$/){
                printlog("ERROR", ARCHDELETE_MS0008, $input_node);
            }
            $backup_node = $input_node;
        }
        else{
            $backup_node = 'localhost';
        }

        printlog("LOG", ARCHDELETE_MS0009);
        my $input_path = <STDIN>;
        chomp $input_path;
        if ($input_path){
            # backup path name format : /<path name>
            if ($input_path !~ /^\/[^\s;|&]*$/){
                printlog("ERROR", ARCHDELETE_MS0010, $input_path);
            }
        }
        $backup_path = $input_path;

        if ($backup_path){
            printlog("LOG", ARCHDELETE_MS0011, $backup_node, $backup_path);
            my $check = <STDIN>;
            chomp $check;
            if ($check !~ m/^y$/i) {
                printlog("LOG", ARCHDELETE_MS0012);
                exit(0);
            }
        }
    }
    
    # バックアップディレクトリパスの末尾の "/" がある場合それを削除
    $backup_path =~ s/\/$//;

    # 環境設定ファイルを読み込み、ツールに必要な情報を取得
    printlog("LOG", ARCHDELETE_MS0013);
    my $config_path = "/etc/pg-rex_tools.conf";
    my %config_value = read_config($config_path);
    my $archivedir = $config_value{'Archive_dir'};

    # PG-REX相手ノードへの ssh 接続の為の情報を取得
    printlog("LOG", ARCHDELETE_MS0044, $config_value{"Another_D-LAN_IPAddress"});
    `$STTY -echo`;
    $ssh_pass_another_node = <STDIN>;
    chomp $ssh_pass_another_node;
    `$STTY echo`;
    printlog("LOG", ARCHDELETE_MS0045);

    # ノード名の取得
    printlog("LOG", ARCHDELETE_MS0015);
    my %node_value = get_node($config_value{'Another_D-LAN_IPAddress'}, $ssh_pass_another_node);

    # PostgreSQL のコマンドパスを取得
    my %command_path = get_pg_command_path($config_value{"PGPATH"});

    # cib.xml ファイルを読み込み、ツールに必要な情報を取得
    printlog("LOG", ARCHDELETE_MS0016);
    my $cib_xml = '/var/lib/heartbeat/crm/cib.xml';
    my %cib_value = read_cib($cib_xml, $command_path{'pg_basebackup'}, $config_value{'PG-REX_Primitive_ResourceID'}, $kill_when_no_data);

    # バックアップの指定無し時の確認
    if (!$backup_path && !$force_mode){
        printlog("LOG", ARCHDELETE_MS0018, $node_value{'my_node'}, $node_value{'another_node'}, $cib_value{'pgdata'});
        my $check = <STDIN>;
        chomp $check;
        if ($check !~ m/^y$/i) {
            printlog("LOG", ARCHDELETE_MS0012);
            exit(0);
        }
    }

    ### バックアップの pgdata の状態を取得 ###
    printlog("LOG", ARCHDELETE_MS0019);

    my $command;
    my $backup_wal = '';
    if ($backup_path){
        printlog("LOG", ARCHDELETE_MS0020);
        $command = "$LS -d $backup_path";
        if ($backup_node ne 'localhost'){
            # バックアップが存在するノードへの ssh 接続の為の情報を取得
            printlog("LOG", ARCHDELETE_MS0044, $backup_node);
            `$STTY -echo`;
            $ssh_pass_backup_node = <STDIN>;
            chomp $ssh_pass_backup_node;
            `$STTY echo`;
            printlog("LOG", ARCHDELETE_MS0045);
            @results = ssh_exec_command($backup_node, "root", $ssh_pass_backup_node, $command);
        }
        else {
            $results[0] = exec_command($command);
            chomp $results[0];
        }
        if ($results[0] ne $backup_path){
            printlog("ERROR", ARCHDELETE_MS0021, $backup_path);
        }
        my $backuplabel = $backup_path."\/backup_label";
        $command = "$CAT $backuplabel";
        if ($backup_node ne 'localhost'){
            @results = ssh_exec_command($backup_node, "root", $ssh_pass_backup_node, $command);
        }
        else {
            $results[0] = exec_command($command);
        }
        my @backuplabel_strings = split(/\n/, $results[0]);
        # backuplabel file first line format : START WAL LOCATION: <xlog location> (file <file name>)
        if (!$backuplabel_strings[0] || $backuplabel_strings[0] !~ /^START\s+WAL\s+LOCATION:\s+[0-9A-F\/]+\s+\(file\s([0-9A-F]+)\)\s*$/){
            printlog("ERROR", ARCHDELETE_MS0022, $backuplabel);
        }
        $backup_wal = $1;
        printlog("LOG", ARCHDELETE_MS0023, $backup_wal);
    }

    # 自身のノードの pgdata の状態を取得
    # pg_controldata コマンドは "C" ロケールにしてから実行
    printlog("LOG", ARCHDELETE_MS0024, $node_value{'my_node'}, $cib_value{'pgdata'});
    my $my_wal = '';

    $result = exec_command("$SU - postgres -c \"export LANG=C; $command_path{'pg_controldata'} $cib_value{'pgdata'}\"");
    if ($result ne ''){
        my @my_controldata_strings = split(/\n/, $result);
        $my_wal = get_recoverywal(@my_controldata_strings);
        printlog("LOG", ARCHDELETE_MS0023, $my_wal);
    }
    else{
        printlog("ERROR", ARCHDELETE_MS0025);
    }

    # 相手のノードの pgdata の状態を取得
    # pg_controldata コマンドは "C" ロケールにしてから実行
    printlog("LOG", ARCHDELETE_MS0026, $node_value{'another_node'}, $cib_value{'pgdata'});
    my $another_wal = '';

    @results = ssh_exec_command($config_value{'Another_D-LAN_IPAddress'}, "root", $ssh_pass_another_node, "$SU - postgres -c \"export LANG=C; $command_path{'pg_controldata'} $cib_value{'pgdata'}\"");
    if ($results[0] ne ''){
        my @another_controldata_strings = split(/\n/, $results[0]);
        $another_wal = get_recoverywal(@another_controldata_strings);
        printlog("LOG", ARCHDELETE_MS0023, $another_wal);
    }
    else{
        printlog("ERROR", ARCHDELETE_MS0025);
    }

    ### 削除基準の WAL の算出 ###
    # 削除基準は、指定したベースバックアップ、自身のノードの PGDATA 、相手先のノードの PGDATA の
    # リカバリに必要な最初の WAL ファイルの中で一番小さいファイルを選ぶ
    printlog("LOG", ARCHDELETE_MS0027);

    my $base_wal = '';
    my @comparelist = ($backup_wal, $my_wal, $another_wal);
    foreach my $wal (@comparelist){
        if ($wal ne ''){
            if ($base_wal eq ''){
                $base_wal = $wal;
            }
            elsif ($wal lt $base_wal){
                $base_wal = $wal;
            }
        }
    }
    if ($base_wal eq ''){
        printlog("LOG", ARCHDELETE_MS0028);
        exit(0);
    }
    else{
        printlog("LOG", ARCHDELETE_MS0029, $base_wal);
    }

    ### アーカイブファイルリストの作成 ###
    printlog("LOG", ARCHDELETE_MS0030);

    my @filelist = ();
    opendir(DIR, $archivedir) or printlog("ERROR", ARCHDELETE_MS0031, $archivedir);
    while (my $archivefile = readdir DIR){
        # archive xlogfile name format : <xlogfile name>
        # <xlogfile name> : <TimeLineID><startxlogfile name>
        # <TimeLineID>は8桁の16進数
        # <startxlogfile name>は16桁の16進数
        #
        # archive backupfile name format : <backupfile name>
        # <backupfile name> : <xlogfile name>.<xlog location>.backup
        # <xlog location>は8桁の16進数
        #
        # archive historyfile name format : <historyfile name>
        # <historyfile name>: <TimeLineID>.history
        # <TimeLineID>は8桁の16進数
        if ($archivefile =~ /^[0-9A-F]{8}((\.history)|([0-9A-F]{16}(\.[0-9A-F]{8}\.backup)?))$/){
            push(@filelist, $archivefile);
        }
    }
    closedir(DIR);

    # アーカイブ削除対象の算出
    
    # historyfile name format : <TimeLineID>.history
    # <TimeLineID>は8桁の16進数
    $base_wal =~ /^([0-9A-F]{8})/;
    my $base_history = $1;
    my @removelist = ();
    foreach my $file (@filelist){
        if ($file =~ /^[0-9A-F]{8}\.history$/) {
            if ($file lt $base_history){
                printlog("LOG", ARCHDELETE_MS0032, $file);
                push(@removelist, $file);
            }
        }
        elsif ($file lt $base_wal){
            printlog("LOG", ARCHDELETE_MS0032, $file);
            push(@removelist, $file);
        }
    }
    if (!@removelist){
        printlog("LOG", ARCHDELETE_MS0033);
        exit(0);
    }

    # アーカイブログの削除
    if ($mode eq "mv"){
        my ($sec, $min, $hour, $mday, $mon, $year) = localtime(time());
        my $date = sprintf("%04d%02d%02d_%02d%02d%02d", $year+1900, $mon+1, $mday,
                            $hour, $min, $sec);
        my $movedir = $archivedir."/".$date;
        if (-d $movedir){
            printlog("ERROR", ARCHDELETE_MS0034, $movedir);
        }
        mkdir($movedir, 0700) or printlog("ERROR", ARCHDELETE_MS0035, $movedir);
        chown(26, 26, $movedir) or printlog("ERROR", ARCHDELETE_MS0036, $movedir);
        printlog("LOG", ARCHDELETE_MS0037, $movedir);
        
        foreach my $movefile (@removelist){
            my $movepath = $archivedir."/".$movefile;
            rename($movepath, $movedir."/".$movefile) or printlog("ERROR", ARCHDELETE_MS0038, $movepath);
            printlog("LOG", ARCHDELETE_MS0039, $movefile);
        }

        printlog("LOG", ARCHDELETE_MS0040, $movedir);
    }
    else {
        foreach my $removefile (@removelist){
            my $removepath = $archivedir."/".$removefile;
            unlink($removepath) or printlog("ERROR", ARCHDELETE_MS0041, $removepath);
            printlog("LOG", ARCHDELETE_MS0042, $removefile);
        }
        printlog("LOG", ARCHDELETE_MS0043);
    }
    exit(0);
}