rem /***********************************************************************/
rem /*  このファイルでは、openGionを起動するための環境変数を設定します。   */
rem /*  通常、このファイルを変更する必要はありません。                     */
rem /***********************************************************************/

rem /***********************************************************************/
rem /*  JavaとTomcatのパス設定です。                                       */
rem /***********************************************************************/
set APPS=%~dp0..\..\apps
set UAP=%~dp0..

set JAVA_HOME=%APPS%\%JDK_VER%
set CATALINA_HOME=%APPS%\%TOMCAT_VER%
set EXT_DIR=%APPS%\%EXT_VER%

rem /***********************************************************************/
rem /*  Tomcatのserver.xmlに引き渡す各種変数設定                           */
rem /***********************************************************************/
set ENGINE_NAME=tomcat
set APP_BASE=%UAP%\webapps
rem set SYS_LOG_URL=log/%COMPUTERNAME%_%ENGINE_NAME%_$(yyyyMM).log
set WORK_DIR=%CATALINA_HOME%\work
set LOGS_DIR=%CATALINA_HOME%\logs

rem /***********************************************************************/
rem /*  OpenOffice帳票用設定(openoffice4.1.X と、LibreOffice_6.1.X 共通)   */
rem /*   ① 64bit版OSを使用時は、ｼｽﾃﾑﾘｿｰｽ REPORT_OOO_CONN_TYPE = "TCP"     */
rem /*   ② 3.4.1 , 4.1.1 使用時は、                                       */
rem /*        ツール＞オプション＞Calc＞印刷＞選択したシートのみ印刷       */
rem /*      のチェックをはずし、「ユーザー登録済みの環境設定」を、コピー   */
rem /*   ③ openoffice3.2、openoffice3.4.1 はサポート取りやめ              */
rem /***********************************************************************/

rem /for や if の中で、環境変数を使用する場合、遅延環境変数(SETLOCAL enabledelayedexpansion)
rem /の設定が必要だが、うまくいかないので、goto文で飛ばすことにします。

if not defined OPENOFFICE_VER goto :SKIP_OFFICE
	set OFFICE_HOME=%APPS%\%OPENOFFICE_VER%
	set CLASSPATH=%OFFICE_HOME%\program\classes\juh.jar;%OFFICE_HOME%\program\classes\unoil.jar;

	set PATH=%OFFICE_HOME%\program;%PATH%;
:SKIP_OFFICE

rem /***********************************************************************/
rem /*  DERBY_DIR JavaDB ﾄﾞﾗｲﾊﾞのｸﾗｽﾊﾟｽ設定                                */
rem /*   JDBC4.0 では、ドライバー指定を書く必要は無いが、openGion が未対応 */
rem /*       derby.jar        組み込み環境。（クラサバ環境でも必要）       */
rem /*       derbyclient.jar  クライアント/サーバー環境                    */
rem /*       derbytools.jar   JDBCが derbyclient から derbytools に移動    */
rem /*                        (10.15.1.3)                                  */
rem /*   DERBYのログは、TomcatのLOGS_DIRに作成します。                     */
rem /*   ※ CLASSPATH に追記すると、* でｴﾗｰになるので、DB_CLSPATH とする   */
rem /***********************************************************************/
if not defined DERBY_VER goto :SKIP_DERBY
	set DERBY_DIR=%APPS%\%DERBY_VER%
	set DB_CLSPATH=%DERBY_DIR%\lib\*;

	set DERBY_OPTS=-Dderby.stream.error.file=%LOGS_DIR%\derby.log
:SKIP_DERBY

rem /***********************************************************************/
rem /*  Tomcat起動用の設定です。                                           */
rem /*    %CATALINA_HOME%\bin\catalina.bat で、CLASSPATH がクリアされる。  */
rem /*    setenv.bat を追加して、OG_CLASSPATH を CLASSPATH に再設定        */
rem /***********************************************************************/
set OG_CLASSPATH=%CLASSPATH%;%EXT_DIR%\*;%DB_CLSPATH%;

rem /***********************************************************************/
rem /*  コンテキストパスの設定                                             */
rem /***********************************************************************/
set DEV_PATH=%APP_BASE%\%DEV_CTXT%
set CORE_PATH=%APP_BASE%\%CORE_CTXT%

rem /***********************************************************************/
rem /*  その他設定                                                         */
rem /***********************************************************************/
set CATALINA_OPTS=%CATALINA_OPTS% -server %JAVA_OPTS%			^
	-DshutdownPort=%SHUTDOWN_PORT%								^
	-DconnectorPort=%CONNECTOR_PORT%							^
	-DajpPort=%AJP_PORT%										^
	-DengineName=%ENGINE_NAME%									^
	-DconnectionDriver=%REALM_DRIVER%							^
	-DconnectionUrl=%REALM_URL%									^
	-DconnectionName=%REALM_NAME%								^
	-DconnectionPassword=%REALM_PASSWORD%						^
	-DappBase=%APP_BASE%										^
	-DworkDir=%WORK_DIR%										^
	-DlogsDir=%LOGS_DIR%

set PATH=%JAVA_HOME%\bin;%PATH%;
set TITLE=%VIEW_NAME% ( %CONNECTOR_PORT% ) %JDK_VER% %TOMCAT_VER% %OPENOFFICE_VER% %~dp0
